/*
 * Copyright (c) 1998-2007 Caucho Technology -- all rights reserved
 *
 * This file is part of Resin(R) Open Source
 *
 * Each copy or derived work must preserve the copyright notice and this
 * notice unmodified.
 *
 * Resin Open Source is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * Resin Open Source is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE, or any warranty
 * of NON-INFRINGEMENT.  See the GNU General Public License for more
 * details.
 *
 * You should have received a copy of the GNU General Public License
 * along with Resin Open Source; if not, write to the
 *
 *   Free Software Foundation, Inc.
 *   59 Temple Place, Suite 330
 *   Boston, MA 02111-1307  USA
 *
 * @author Emil Ong
 */

package com.caucho.ria.examples.words;

import javafx.ui.*;
import javafx.ui.canvas.*;

class Poem {
  attribute wordNodes:WordNode*;
  attribute i:Integer;
  attribute submitter:String;
}

// For some reason, we can't really bind to an array, we need a wrapper
// object... 
class PoemModel {
  attribute poems:Poem*;
}

class ReadTab extends Tab {
  attribute model:PoemModel;
  attribute listBox:ListBox;
}

attribute ReadTab.title = "Read";
attribute ReadTab.model = new PoemModel();

operation ReadTab.getListBox():ListBox {
  if (listBox == null) {
    listBox = ListBox {
      cells: bind foreach (poem in model.poems)
                    ListCell { 
                      text: "Poem {poem.i} ({poem.submitter})"
                      value: poem
                    }
    };
  }

  return listBox;
}

attribute ReadTab.content = Box {
  orientation: VERTICAL:Orientation
  content: [
    GridPanel {
      rows: 1
      columns: 2

      cells: [ 
        getListBox(),
        Canvas {
          scaleToFit: false
          content: Group {
            content:
            bind ((Poem) listBox.cells[listBox.selection].value).wordNodes
          }
        }
      ]
    },

    Button {
      alignmentX: 0.5

      text: "Get Poems from Server"
      action: operation() {
        refresh();
      }
    }
  ]
};

operation ReadTab.refresh() {
  var recent = WordClient.CLIENT.getRecent();
  var wordIter = recent.iterator();
  delete model.poems;
  var i = 1;

  while (wordIter.hasNext()) {
    var wordSet = (WordSet) wordIter.next();
    var poem = Poem { wordNodes:[], i:i, submitter: wordSet.getSubmitter() };

    var iter = wordSet.getWords();
    while (iter.hasNext()) {
      var word = (Word) iter.next();

      insert WordNode {
        value: word.getText()
        x: word.getX()
        y: word.getY()
        word: word
        readOnly: true
      } as last into poem.wordNodes;
    }

    insert poem as last into model.poems;
    i++;
  }
}