src/com/caucho/ria/examples/words/ComposeTab.fx

/*
 * Copyright (c) 1998-2007 Caucho Technology -- all rights reserved
 *
 * This file is part of Resin(R) Open Source
 *
 * Each copy or derived work must preserve the copyright notice and this
 * notice unmodified.
 *
 * Resin Open Source is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * Resin Open Source is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE, or any warranty
 * of NON-INFRINGEMENT.  See the GNU General Public License for more
 * details.
 *
 * You should have received a copy of the GNU General Public License
 * along with Resin Open Source; if not, write to the
 *
 *   Free Software Foundation, Inc.
 *   59 Temple Place, Suite 330
 *   Boston, MA 02111-1307  USA
 *
 * @author Emil Ong
 */

package com.caucho.ria.examples.words;

import javafx.ui.*;
import javafx.ui.canvas.*;

class ComposeTab extends Tab {
  attribute wordNodes:WordNode*;
  attribute wordSet:WordSet;
}

attribute ComposeTab.title = "Compose";
attribute ComposeTab.wordNodes = [];
attribute ComposeTab.wordSet = Word.getDefaultWords();

attribute ComposeTab.content = Box {
  orientation: VERTICAL:Orientation
  content: [
    Label {
      text: "<html><b>Drag words from left to right -></b><br><hr></html>"
      alignmentX: 0.5
    },
    Canvas {
      doubleBuffered: true
      alignmentX: 0.5
      content: Group {
        content: bind [
          wordNodes,
          Line {
            x1: 202
            y1: 0
            x2: 202
            y2: 199
            stroke: black
          }
        ]
      }
    },
    Box {
      content: [
        Button {
          text: "Reset"
          action: operation() {
            reset();
          }
        },
        Button {
          text: "Send to Server"
          action: operation() {
            submit();
          }
        },
      ]
    }
  ]
};

trigger on new ComposeTab {
  var iter = wordSet.getWords();

  while (iter.hasNext()) {
    var word = (Word) iter.next();

    insert WordNode {
      value: word.getText()
      x: word.getX()
      y: word.getY()
      word: word
      readOnly: false
    } as last into wordNodes;
  }
}

operation ComposeTab.reset() {
  for (node in wordNodes) {
    node.word.reset();
    node.x = node.word.getX();
    node.y = node.word.getY();
  }
}

operation ComposeTab.submit() {
  WordClient.CLIENT.submit(wordSet);
}